APM ActionScript リファレンス

全件検索で「クラス」を検索した結果、66件ヒットしました。

FileReferenceList (flash.net.FileReferenceList) クラス

使用可能バージョン【FlashPlayer8 】
使用可能ActionScriptバージョン【ActionScript1.0 】

public class FileReferenceList
extends Object

FileReferenceList クラスには、ユーザーがアップロードするファイルを選択する手段 (複数選択可能) があります。

FileReferenceList オブジェクトは、ユーザーのディスク上にあるローカルファイルを FileReference オブジェクトの配列として表現します。FileReference オブジェクトと FileReference クラスの詳細および重要な考慮事項については、「FileReference クラス」を参照してください。これらは FileReferenceList で使用します。

FileReferenceList クラスを使用するには

このクラスのインスタンスを作成します。 var myFileRef = new FileReferenceList();
FileReferenceList.browse() を呼び出して、ユーザーがアップロードするファイルを選択できるダイアログボックスを表示します。 myFileRef.browse();
browse() が正常に呼び出された後、FileReferenceList オブジェクトの fileList プロパティに FileReference オブジェクトの配列が設定されます。
fileList 配列内の各エレメントについて FileReference.upload() を呼び出します。

FileReferenceList クラスには、browse() メソッドや、複数のファイルを使用するための fileList プロパティなどがあります。

次の例では、ユーザーが複数のファイルを選択して、サーバーにアップロードできます。

import flash.net.FileReferenceList;
import flash.net.FileReference;

var listener:Object = new Object();

listener.onSelect = function(fileRefList:FileReferenceList) {trace("onSelect");
var list:Array = fileRefList.fileList;
var item:FileReference;
for(var i:Number = 0; i < list.length; i++) {
item = list[i];
trace("name: " + item.name);
trace(item.addListener(this));
item.upload("http://www.yourdomain.com/");
}
}

listener.onCancel = function():Void {
trace("onCancel");
}

listener.onOpen = function(file:FileReference):Void {
trace("onOpen: " + file.name);
}

listener.onProgress = function(file:FileReference, bytesLoaded:Number,
bytesTotal:Number):Void {
trace("onProgress with bytesLoaded: " + bytesLoaded + " bytesTotal: " + bytesTotal);
}

listener.onComplete = function(file:FileReference):Void {
trace("onComplete: " + file.name);
}

listener.onHTTPError = function(file:FileReference, httpError:Number):Void {
trace("onHTTPError: " + file.name + " httpError: " + httpError);
}

listener.onIOError = function(file:FileReference):Void {
trace("onIOError: " + file.name);
}

listener.onSecurityError = function(file:FileReference, errorString:String):Void {
trace("onSecurityError: " + file.name + " errorString: " + errorString);
}

var fileRef:FileReferenceList = new FileReferenceList();
fileRef.addListener(listener);
fileRef.browse();

プロパティ一覧

オプション	プロパティ	説明
	fileList:Array	FileReferenceオブジェクトの配列です。

イベントの一覧

イベント	説明
onCancel=function(fileRefList:FileReferenceList){}	ユーザーがファイル参照ダイアログボックスを閉じると、呼び出されます。
onSelect=function(fileRefList:FileReferenceList){}	ユーザーがアップロードするファイルをファイル参照ダイアログボックスから1つ以上選択したときに呼び出されます。

コンストラクタ一覧

署名	説明
FileReferenceList()	新しいFileReferenceListオブジェクトを作成します。

メソッド一覧

オプション	署名	説明
	addListener(listener:Object):Void	FileReferenceListイベントリスナーが呼び出されたときに通知を受けるオブジェクトを登録します。
	browse([typelist:Array]):Boolean	アップロードするローカルファイルを1つ以上選択できるファイル参照ダイアログボックスを表示します。
	removeListener(listener:Object):Boolean	イベント通知メッセージを受信するオブジェクトのリストからオブジェクトを削除します。

FileReferenceList (flash.net.FileReferenceList) クラスのページトップへ

APM Action Script リファレンス

FileReferenceList (flash.net.FileReferenceList) クラス

プロパティ一覧

イベントの一覧

コンストラクタ一覧

メソッド一覧